Prototype ¬ Detail

author: lost nation [+], Submitted: 07.17.03 9a • Last Edit: 01.09.04 11a

MovieClip.prototype.vegasText = function(mode, arr, x, y, z, speed, txtFont, txtColor, txtSize, showShadow, shadowColor, margin, repeat, offset) {
	this.y=y;
	this.index=0;
	this.printIt = function(y) {
		mode==2 ? this['line_mc'+(this.index-1)].removeMovieClip() : null;
		this.createEmptyMovieClip('line_mc'+this.index, this.index);
		var cage = this['line_mc'+this.index];
		cage._x = x;
		cage._y = y;
		cage.str = arr[this.index];
		cage.chars = cage.str.length;
		for (i=0; i<cage.str.length; i++) {
			cage.createEmptyMovieClip('char_'+i, i);
			cage['char_'+i].id = i;
			cage['char_'+i].s = i*speed;
			cage['char_'+i].baseChar = cage.str.charAt(i);
			with (cage['char_'+i]) {
				i == 0 ? _x=0 : _x=_parent['char_'+(i-1)]._x+_parent['char_'+(i-1)].char_txt.textWidth;
				createTextField('char_txt', 2, 0, 0, 0, 0);
				with (char_txt) {
					var f = new TextFormat(txtFont, txtSize, txtColor);
					setNewTextFormat(f);
					embedFonts = true;
					autosize = true;
					selectable = false;
					text = _parent.baseChar;
				}
				if (showShadow) {
					createTextField('charShad_txt', 1, 1, 1, 0, 0);
					with (charShad_txt) {
						var f = new TextFormat(txtFont, txtSize, shadowColor);
						setNewTextFormat(f);
						embedFonts = true;
						autosize = true;
						selectable = false;
						text = _parent.baseChar;
					}
				}
			}
			cage['char_'+i].onEnterFrame = function() {
				this.i++;
				this.j++;
				if (this.j<this.s) {
					if (this.i<this._parent.chars) {
						var v = this._parent.str.charAt(random(this._parent.chars));
						if (showShadow) {
							this.char_txt.text = v;
							this.charShad_txt.text = v;
						} else {
							this.char_txt.text = v;
						}
					} else {
						this.i = 0;
					}
				} else {
					var mc = this._parent._parent;
					var l = arr.length;
					if (showShadow) {
						this.char_txt.text = this.baseChar;
						this.charShad_txt.text = this.baseChar;
					} else {
						this.char_txt.text = this.baseChar;
					}
					if((mc.index-1)<l && this.id == this._parent.chars-1){
						if((mc.index)<l){
							if(mode==1){
								mc.printIt(mc['line_mc'+(mc.index-1)]._y+mc['line_mc'+(mc.index-1)].char_0.char_txt.textHeight+margin);
							}else{
								mc.printIt(mc.y);
							}
						}else if(repeat){
							_root.reset(mc, mc.index, offset);
						}
					}
					this.onEnterFrame = null;
				}
			};
		}
		this.index++;
	};
	this.printIt(this.y);
};
this.reset = function(mc, n, t) {
	mc.index = 0;
	if (t != undefined) {
		var int=mc+'wait';
		int = setInterval(function () {
			for (i=n; i>0; i--) {
				mc['line_mc'+i].removeMovieClip();
			}
			mc.printIt(mc.y);
			clearInterval(int);
		}, t);
	} else if (mc.t == undefined) {
		mc.printIt(mc.y);
	}
};

usage

Description:

This prototype creates a 'slot machine' text effect within a movieclip, hence the name 'VegasText.' 
View the sample at the URL below for a sample.

Arguments:

'mode' - 1: each new element is a new line, 2: each new element is the same line (number)
'arr'  - array of text strings to display (array)
'x' - _x location of clip (number)
'y' - _y location of clip (number)
'z' - initial depth of clip, will increment for each new line (number)
'speed' - number of random characters to display before reverting to home character (number)
'txtFont' - linkageID of Font symbol (string)
'txtColor' - text color (color)
'txtSize' - text size (number)
'showShadow' - show text shadow or not (boolean)
'shadowColor' - text shadow color (color)
'margin' - vertical offset between lines (number)
'repeat' - whether or not to repeat after first cycle (boolean)
'offset' - number of milliseconds between cycles

Usage:

this.createEmptyMovieClip('mc', 1);
this.mc.vegasText(1,['ACTIONSCRIPT FOR FLASH MX', 'The Definitive Guide', 'by Colin Moock'], 200, 180, 1, 5, 'Font', 0xCCFF00, 20, true, 0x333333, 0, true, 1000);

Sample:

[url="http://looklisten.net/view_content.php?id=7"]looklisten.net/view_content.php?id=7[/url]